AbstractKCM.qml

/*
    SPDX-FileCopyrightText: 2020 Marco Martin <[email protected]>

    SPDX-License-Identifier: LGPL-2.0-or-later
*/

import QtQuick 2.7
import QtQuick.Controls 2.2 as QtControls
import org.kde.kirigami 2.14 as Kirigami
import org.kde.kcm 1.1 as KCM

Kirigami.Page {
    id: root

    title: kcm.name

    // Make pages fill the whole view by default
    Kirigami.ColumnView.fillWidth: true

    leftPadding: 6 // Layout_ChildMarginWidth from Breeze
    topPadding: headerParent.contentItem ? 0 : leftPadding
    rightPadding: leftPadding
    bottomPadding: footerParent.contentItem ? 0 : leftPadding

    header: QtControls.Control {
        id: headerParent
        height: contentItem ? implicitHeight : 0
        leftPadding: 6 // Layout_ChildMarginWidth from Breeze
        topPadding: leftPadding
        rightPadding: leftPadding
        bottomPadding: leftPadding
    }

    footer: QtControls.Control {
        id: footerParent
        height: contentItem ? implicitHeight : 0
        leftPadding: 6 // Layout_ChildMarginWidth from Breeze
        topPadding: leftPadding
        rightPadding: leftPadding
        bottomPadding: leftPadding
    }

    Component.onCompleted: {
        if (footer && footer != footerParent) {
            var f = footer

            footerParent.contentItem = f
            footer = footerParent
            footer.visible = true
            f.parent = footerParent
        }

        if (header && header != headerParent) {
            var h = header

            headerParent.contentItem = h
            header = headerParent
            header.visible = true
            h.parent = headerParent
        }

        //Search overlaysheets in contentItem, parent to root if found
        for (let i in contentItem.data) {
            let child = contentItem.data[i];
            if (child instanceof Kirigami.OverlaySheet) {
                if (!child.parent) {
                    child.parent = root;
                }
                root.data.push(child);
            }
        }
    }
}