ConditionalLoader.qml

Go to the documentation of this file.

import QtQuick 1.1

Item {
    id: root

    property alias when: loader.when

    property alias source: loader.conditionalSource

    property alias item: loader.item

    implicitWidth: loader.item ? loader.item.implicitWidth : 0
    implicitHeight: loader.item ? loader.item.implicitHeight : 0

    Loader {
        id: loader
        anchors.fill: parent

        property bool when: false
        property variant conditionalSource

        //internal
        property variant oldConditionalSource

        onWhenChanged: loadTimer.restart()
        onConditionalSourceChanged: loadTimer.restart()

        Timer {
            id: loadTimer
            interval: 0

            onTriggered: {
                if (loader.when &&
                    (loader.item === null ||
                     loader.conditionalSource !== loader.oldConditionalSource)) {
                    if (typeof(loader.conditionalSource) === "string") {
                        loader.source = loader.conditionalSource
                    } else {
                        loader.sourceComponent = loader.conditionalSource
                    }
                    loader.oldConditionalSource = loader.conditionalSource
                    loader.item.visible = true
                    loader.item.anchors.fill = loader.item.parent
                }
            }
        }
    }
}