AboutPage.qml

/*
 *   Copyright (C) 2018 Aleix Pol Gonzalez <aleixpol@blue-systems.com>
 *
 *   This program is free software; you can redistribute it and/or modify
 *   it under the terms of the GNU Library/Lesser General Public License
 *   version 2, or (at your option) any later version, as published by the
 *   Free Software Foundation
 *
 *   This program is distributed in the hope that it will be useful,
 *   but WITHOUT ANY WARRANTY; without even the implied warranty of
 *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *   GNU General Public License for more details
 *
 *   You should have received a copy of the GNU Library/Lesser General Public
 *   License along with this program; if not, write to the
 *   Free Software Foundation, Inc.,
 *   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
 */

import QtQuick 2.1
import QtQuick.Controls 2.4 as QQC2
import QtQuick.Layouts 1.3
import org.kde.kirigami 2.5

ScrollablePage
{
    id: page
    property var aboutData

    title: qsTr("About")
    Component {
        id: licencePage
        ScrollablePage {
            property alias text: content.text
            QQC2.TextArea {
                id: content
                readOnly: true
            }
        }
    }

    Component {
        id: personDelegate
        AbstractCard {
            Layout.fillWidth: true
            contentItem: RowLayout {
                Layout.preferredHeight: Units.iconSizes.medium
                Icon {
                    Layout.fillHeight: true
                    Layout.alignment: Qt.AlignVCenter
                    Layout.minimumWidth: Units.iconSizes.medium
                    Layout.maximumWidth: Units.iconSizes.medium
                    source: "user" //TODO: use ocs once we don't need to depend on attica, was using gravatar but it didn't feel right
                    fallback: "user"
                }
                QQC2.Label {
                    Layout.fillWidth: true
                    text: qsTr("%1 <%2>").arg(modelData.name).arg(modelData.emailAddress);
                }
            }
        }
    }

    ColumnLayout {
        GridLayout {
            columns: 2
            Layout.fillWidth: true

            Icon {
                Layout.rowSpan: 2
                Layout.preferredHeight: Units.iconSizes.huge
                Layout.preferredWidth: height
                Layout.maximumWidth: page.width / 3;
                Layout.rightMargin: Units.largeSpacing
                source: page.aboutData.programLogo || page.aboutData.programIconName
            }
            Heading {
                Layout.fillWidth: true
                text: page.aboutData.displayName + " " + page.aboutData.version
            }
            Heading {
                Layout.fillWidth: true
                level: 2
                text: page.aboutData.shortDescription
            }
        }

        Separator {
            Layout.fillWidth: true
        }

        Heading {
            text: qsTr("Copyright")
        }
        QQC2.Label {
            Layout.leftMargin: Units.gridUnit
            text: aboutData.otherText
            visible: text.length > 0
        }
        QQC2.Label {
            Layout.leftMargin: Units.gridUnit
            text: aboutData.copyrightStatement
            visible: text.length > 0
        }
        UrlButton {
            Layout.leftMargin: Units.gridUnit
            url: aboutData.homepage
            visible: url.length > 0
        }

        Repeater {
            model: aboutData.licenses
            delegate: RowLayout {
                Layout.leftMargin: Units.gridUnit
                QQC2.Label { text: qsTr("License:" ) }
                LinkButton {
                    text: modelData.name
                    onClicked: applicationWindow().pageStack.push(licencePage, { text: modelData.text, title: modelData.name } )
                }
            }
        }

        Heading {
            text: qsTr("Libraries in use")
            visible: Settings.information
        }
        Repeater {
            model: Settings.information
            delegate: QQC2.Label {
                Layout.leftMargin: Units.gridUnit
                id: libraries
                text: modelData
            }
        }
        Heading {
            Layout.fillWidth: true
            text: qsTr("Authors")
        }

        Repeater {
            model: aboutData.authors
            delegate: personDelegate
        }
        Heading {
            text: qsTr("Credits")
            visible: repCredits.count > 0
        }
        Repeater {
            id: repCredits
            model: aboutData.translators
            delegate: personDelegate
        }
        Heading {
            text: qsTr("Translators")
            visible: repTranslators.count > 0
        }
        Repeater {
            id: repTranslators
            model: aboutData.translators
            delegate: personDelegate
        }
    }
}