Action.qml

/*
 *   Copyright 2016 Marco Martin <mart@kde.org>
 *
 *   This program is free software; you can redistribute it and/or modify
 *   it under the terms of the GNU Library General Public License as
 *   published by the Free Software Foundation; either version 2 or
 *   (at your option) any later version.
 *
 *   This program is distributed in the hope that it will be useful,
 *   but WITHOUT ANY WARRANTY; without even the implied warranty of
 *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *   GNU Library General Public License for more details
 *
 *   You should have received a copy of the GNU Library General Public
 *   License along with this program; if not, write to the
 *   Free Software Foundation, Inc.,
 *   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
 */

import QtQuick 2.7
import "private"

QtObject {
    id: root

    signal toggled(bool checked)

    
    signal triggered(QtObject source)

    
    property bool visible: true

    property bool checkable: false

    property bool checked: false

    property bool enabled: true

    property alias iconName: iconGroup.name

    property alias iconSource: iconGroup.source

    property ActionIconGroup icon: ActionIconGroup {
        id: iconGroup
    }

    property alias shortcut: shortcutItem.sequence

    property string text

    property string tooltip

    property bool separator: false

    property bool expandible: false

    property QtObject parent

    default property alias children: root.__children
    property list<QtObject> __children

    onChildrenChanged: {
        var child;
        for (var i in children) {
            child = children[i];
            if (child.hasOwnProperty("parent")) {
                child.parent = root
            }
        }
    }

    readonly property var visibleChildren: {
        var visible = [];
        var child;
        for (var i in children) {
            child = children[i];
            if (!child.hasOwnProperty("visible") || child.visible) {
                visible.push(child)
            }
        }
        return visible;
    }

    property Shortcut __shortcut: Shortcut {
        property bool checked: false
        id: shortcutItem
        enabled: root.enabled
        onActivated: root.trigger();
    }
    function trigger(source) {
        if (!enabled) {
            return;
        }
        root.triggered(source);
        if (root.checkable) {
            root.checked = !root.checked;
            root.toggled(root.checked);
        }
    }

    onCheckedChanged: root.toggled(root.checked);
}